Arch Linux User Repository

update for 4.0.3: https://gist.github.com/brett/d686fe0530c268265be48574de1fd98f

Here's a working PKGBUILD:

# Contributor: Jean Lucas <jean@4ray.co>

pkgname=zulip-desktop
pkgver=3.0.0
pkgrel=2
pkgdesc='Real-time team chat based on the email threading model'
arch=(i686 x86_64)
url=https://zulipchat.com
license=(Apache)
depends=(alsa-lib atk at-spi2-atk cairo dbus fontconfig gdk-pixbuf2 glib2 gtk3 hicolor-icon-theme libcups libxcomposite libxcursor libxdamage libxext libxfixes libxi libxkbfile libxrandr libxrender libxss libxtst nspr nss pango)
makedepends=(npm python2 libxkbfile)
source=($pkgname-$pkgver.tar.gz::https://github.com/zulip/$pkgname/archive/v$pkgver.tar.gz
        zulip.desktop)
sha512sums=('a363a05f917a4ad9f563d73e05a613fae92db3f1afbb38aaefb802adea935cce14c684382c0084e9753537d2913caa5edf852123c7035f65f82f76d2c2685e75'
            '7696a6874d17957f99452452723ae1a6b32b6814b018361a71ed1fe0191e1c6da6f3ad693e2e279615e74f687c380ff2f6dab8b69fcd82476e8f33b56a6b4cb5')

prepare() {
  # We need an API key for Sentry, so let's not use it
  sed -i '5s#!##' $pkgname-$pkgver/app/renderer/js/utils/sentry-util.js
}

build() {
  cd $pkgname-$pkgver
  npm i
  npx electron-builder --dir
}

package() {
  install -Dm 644 zulip.desktop -t "$pkgdir"/usr/share/applications

  cd $pkgname-$pkgver

  mkdir "$pkgdir"/usr/{lib,bin}
  cp -a dist/linux-unpacked "$pkgdir"/usr/lib/$pkgname
  ln -s /usr/lib/$pkgname/zulip "$pkgdir"/usr/bin

  for i in 16 24 32 48 64 96 128 256 512; do
    install -Dm 644 build/icons/${i}x${i}.png \
      "$pkgdir"/usr/share/icons/hicolor/${i}x${i}/apps/zulip.png
  done

  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/zulip-desktop
}

and a desktop entry:

[Desktop Entry]
Version=1.0
Type=Application
Name=Zulip
Comment=Real-time team chat based on the email threading model
Exec=zulip
Icon=zulip
Categories=Network;InstantMessaging;
Terminal=false

Hi there! Since this application is open-source, this package should be built from source, and binary distributions of the same should have '-bin' appended to the end of the package name (this package should be 'zulip-desktop-bin').

Validating source files with md5sums ... 0.5.1.tar.gz ... FAILED

The electron implementation can be found here: https://aur.archlinux.org/packages/zulip-electron-bin/

https://github.com/zulip/zulip-desktop says that zulip-desktop is "deprecated in favor of the new electron implementation".

makepkg failed
```cp: cannot stat '/tmp/makepkg/zulip-desktop/src/usr/bin/*': No such file or directory
```
usr/bin/ is empty