Package Details: ytmdesktop-git 1.5.0.1.g5829af5-1

Git Clone URL: https://aur.archlinux.org/ytmdesktop-git.git (read-only)
Package Base: ytmdesktop-git
Description: A desktop app for YouTube Music
Upstream URL: https://ytmdesktop.app
Keywords: electron google music player youtube
Licenses: CCPL
Provides: ytmdesktop
Submitter: garfunkel
Maintainer: garfunkel
Last Packager: garfunkel
Votes: 0
Popularity: 0.000000
First Submitted: 2019-10-09 09:53
Last Updated: 2019-10-09 09:53

Latest Comments

yochananmarqos commented on 2019-11-02 21:14

@sarpik: Thanks, edited.

sarpik commented on 2019-11-02 16:09

@yochananmarqos In the link library part, you forgot the first / before opt:

.........\/ you need a / here

ln -s "opt/${pkgname%-git}/youtube-music-desktop-app" "$pkgdir/usr/bin/${pkgname%-git}"

yochananmarqos commented on 2019-10-09 21:30

  • Don't create unnecessary variables
  • This does not appear to be available for all architectures
  • The license is CC0 1.0 Universal (CC0-1.0) and is in /src/ytmdesktop. You don't need to copy the electron or chromium licenses anywhere, they're already included. Licenses go in /usr/share/licenses/*pkgname*.
  • Electron applications require both nss and libxss. It also appears java-runtime is required.
  • The install file is not required. The desktop cache is updated automatically since pacman 5.0
  • Use a temporary npm cache instead of polluting the user's home directory. See package guidelines
  • Loose files should be installed in /opt/
  • Use install instead of mkdir
pkgname=ytmdesktop-git
pkgver=1.5.0.1.g5829af5
pkgrel=1
pkgdesc="A desktop app for YouTube Music"
arch=('i686' 'x86_64')
url="https://ytmdesktop.app"
license=('CC0-1.0')
depends=('gtk3' 'nss' 'libxss' 'java-runtime')
makedepends=('git' 'npm')
optdepends=('gnome-keyring' 'lsb-release' 'avahi' 'nss-mdns')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/ytmdesktop/ytmdesktop.git'
        "${pkgname%-git}.desktop")
md5sums=('SKIP'
         '63a9f7d805c871f6556aa0e1aa0ef74c')

pkgver() {
    cd "$srcdir/${pkgname%-git}"
    git describe --tags | sed 's/^v//' | sed 's/-/./g'
}

build() {
    cd "$srcdir/${pkgname%-git}"
    rm -rf node_modules
    npm install --cache "$srcdir/npm-cache"

    if [ $CARCH = "x86_64" ]; then
        npm run pack:x64
    elif [ $CARCH = "i686" ]; then
        npm run pack
    fi
}

package() {
    cd "$srcdir/${pkgname%-git}"

    # install license
    install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname%-git}/LICENSE.md"

    # install icon
    install -Dm644 assets/favicon.512x512.png "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"

    # copy application files
    install -dm755 "$pkgdir/opt/${pkgname%-git}"
    cp -r dist/linux-unpacked/* "$pkgdir/opt/${pkgname%-git}"

    # link binary
    install -dm755 "$pkgdir/usr/bin"
    ln -s "/opt/${pkgname%-git}/youtube-music-desktop-app" "$pkgdir/usr/bin/${pkgname%-git}"

    # install desktop entry
    install -Dm644 "$srcdir/${pkgname%-git}.desktop" "$pkgdir/usr/share/applications/${pkgname%-git}.desktop"
}