Package Details: veloren 0.3.0-8

Git Clone URL: https://aur.archlinux.org/veloren.git (read-only)
Package Base: veloren
Description: An open-world, open-source multiplayer voxel RPG
Upstream URL: https://veloren.net/
Keywords: game rpg veloren
Licenses: GPL3
Conflicts: veloren
Provides: veloren
Submitter: Mckol
Maintainer: Mckol
Last Packager: Mckol
Votes: 2
Popularity: 1.191170
First Submitted: 2019-06-23 23:12
Last Updated: 2019-08-11 18:23

Latest Comments

Mckol commented on 2019-08-11 12:59

I've ended up taking some ideas from your PKGBUILD (install is really convenient for binaries since it makes them executable by default) and the dependencies (thanks a lot for that) and incorporating that into the current pkgbuild, I'll upload it soon as I'm still not entirely done and testing some stuff

flacks commented on 2019-08-09 00:37

You're welcome - Haha, everyone has their own formatting style. I just do what I think looks and works best with a focus on minimalism/KISS. The real important things to note, though, are 1) complete depends and makedepends arrays, and 2) a new veloren-chat-cli binary that gets built. If you only do a cargo build from the root workspace (as in build() below), you'll build all three of this release's binaries. Re: veloren-git, you can credit me if you think it's appropriate! :)

Mckol commented on 2019-08-09 00:03

Thank you, I've quickly made the changes you suggested regarding the convention before seeing this comment, but your PKGBUILD looks way cleaner than mine, I'm gonna use most of it. I'll probably copy the package() method to veloren-git, should I also credit you there?

flacks commented on 2019-08-08 19:46

Here's a working PKGBUILD with a complete dependency list and updated desktop entry:

# Contributor: Jean Lucas <jean@4ray.co>

pkgname=veloren
pkgver=0.3.0
pkgrel=6
pkgdesc='Open-world, open-source, multiplayer voxel RPG'
arch=(i686 x86_64)
url=https://veloren.net
_git=https://gitlab.com/veloren/veloren
license=(GPL3)
depends=(gtk3)
makedepends=(git git-lfs rustup cairo alsa-lib pango atk gdk-pixbuf2)
source=(git+$_git#tag=v$pkgver
        veloren.desktop
        veloren.png)
sha512sums=('SKIP'
            'efeee59ef68e88f687aaf450f59de4136f4d871ab66cdccf75054e9439c9bcc02e02ad6ccce8c11cc9d5c1f94b4d080086eee8cec09d5e6ace8e5e085fe7936e'
            'b5e5cbf28ab0e335f5a0fc93511fc9936360432a36e35cc876761601abacf257299deb0af6b3d9081143b700f6663c4f603970155dd4dacedb7a9672cde1dc94')

prepare() {
  cd veloren
  # Download large assets
  git remote set-url origin $_git
  git lfs install
  git lfs fetch
  git lfs checkout
}

build() {
  cd veloren
  cargo build --release
}

package() {
  cd veloren

  install -D target/release/veloren-{voxygen,chat-cli,server-cli} -t "$pkgdir"/usr/bin

  install -d "$pkgdir"/usr/share/veloren
  cp -a {assets,voxygen/shaders} "$pkgdir"/usr/share/veloren

  install -Dm 644 ../veloren.desktop -t "$pkgdir"/usr/share/applications
  install -Dm 644 ../veloren.png -t "$pkgdir"/usr/share/pixmaps

  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/veloren
}
[Desktop Entry]
Version=1.0
Type=Application
Name=Veloren
Comment=Open-world, open-source, multiplayer voxel RPG
Exec=veloren-voxygen
Icon=veloren
Categories=Game;
Terminal=true

flacks commented on 2019-08-08 16:01

Hi there! Since Veloren is libre software, by convention, this package should be built from source, and binary distributions of the package should have '-bin' appended to the AUR package name.

Mckol commented on 2019-08-05 17:50

I've fixed both issues

grayich commented on 2019-08-05 14:41

==> Starting package()...
cp: cannot stat '/home/gray/veloren/src/veloren-voxygen-run': No such file or directory
==> ERROR: A failure occurred in package().
    Aborting...

ax34 commented on 2019-08-05 01:29

...
==> Validating source files with sha512sums...
    veloren ... Passed
    voxygen.desktop ... FAILED
    voxygen.png ... Passed
==> ERROR: One or more files did not pass the validity check!

sha512sum of your voxygen.desktop is 209a1c66fcdb932df5472084e42213ee4820f07066a189f5ccb0f1a62becff3cdbaf4e00bc15534b287b02bccc1faa792649a1eff8b2d6d218b8b3692ed3a703 while sha512sum in PKGBUILD is 88f067450ada7cd774435b196319d820d99f60e9f0c0561b6ae99191b969b00e2573d47445327e3a4d0bf733dd937d5f804f91f5ce7001f79077a8a8e4f9757d