Package Details: ruby-puma 5.2.1-2

Git Clone URL: https://aur.archlinux.org/ruby-puma.git (read-only, click to copy)
Package Base: ruby-puma
Description: A Ruby/Rack web server built for concurrency
Upstream URL: https://puma.io/
Licenses: BDS-3-CLAUSE
Submitter: Segaja
Maintainer: Segaja
Last Packager: Segaja
Votes: 0
Popularity: 0.000000
First Submitted: 2021-02-24 22:05
Last Updated: 2021-02-28 22:39

Required by (0)

Sources (1)

Latest Comments

Segaja commented on 2021-02-28 22:40

@bastelfreak: i updated this package with most of your suggestions but i left the tests out, since they are not working yet.

bastelfreak commented on 2021-02-25 21:51

hey, so I would like to move this to community including tests (it's one of the missing test requirements for faraday). I can now successfully start the tests, but they do not yet pass:

# Maintainer: Tim Meusel <tim@bastelfreak.de>
# Contributor: Andreas 'Segaja' Schleifer <archlinux at segaja dot de>

_gemname=puma
pkgname="ruby-${_gemname}"
pkgver=5.2.1
pkgrel=2
pkgdesc='A Ruby/Rack web server built for concurrency'
arch=(any)
url='https://puma.io/'
license=(BSD-3-CLAUSE)
options=(!emptydirs)
depends=('ruby' 'ruby-nio4r' 'ruby-sd_notify')
makedepends=('git' 'ruby-rake' 'ruby-bundler' 'ruby-rdoc' 'ruby-rake-compiler')
checkdepends=('ruby-rack' 'ruby-minitest' 'ruby-minitest-stub-const' 'ruby-minitest-proveit' 'ruby-minitest-retry')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/puma/puma/archive/v${pkgver}/${_gemname}-v${pkgver}.tar.gz")
sha512sums=('8ec1a351badd68ce6559eb99592e3f4d836ca49406749a6c2cd9162c443eadf3b4cf24ceb6c92e0e27057217f6487ff9923888ff4a1590f8cf9061d06ec16e52')

prepare() {
  cd "${srcdir}/${_gemname}-${pkgver}"

  # update gemspec/Gemfile to allow newer version of the deps
  sed -r 's|~>|>=|g' -i "${_gemname}.gemspec" Gemfile

  # we built based on a tar archive, not a git repo
  sed --in-place 's/git ls-files/find/' "${_gemname}.gemspec"
  # disable rubocop, we don't have that in our repos and it doesn't provide any benefits during building
  sed --in-place '/rubocop/Id' Rakefile Gemfile

  # disable m. Only required for debugging during development
  sed --in-place "/'m'/d" Gemfile
}

build() {
  cd "${srcdir}/${_gemname}-${pkgver}"

  #gem build "${_gemname}.gemspec"
  rake build
}

check() {
  cd "${srcdir}/${_gemname}-${pkgver}"
  #rake -T
  rake test --trace
}
package() {
  cd "${srcdir}/${_gemname}-${pkgver}"

  local _gemdir="$(gem env gemdir)"

  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem

  rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"

  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  install -Dm 644 README.md 5.0-Upgrade.md CODE_OF_CONDUCT.md CONTRIBUTING.md History.md Release.md SECURITY.md  -t "${pkgdir}/usr/share/doc/${pkgname}"
}

I also created the following packages: * ruby-minitest-stub-const * ruby-minitest-proveit * ruby-minitest-retry * ruby-sd_notify