Package Details: python-networkx-git 2.6rc1.r1.gc444024a5-1

Git Clone URL: https://aur.archlinux.org/python-networkx-git.git (read-only, click to copy)
Package Base: python-networkx-git
Description: Python package for the creation, manipulation, and study of the structure, dynamics, and functions of complex networks.
Upstream URL: https://github.com/networkx/networkx
Licenses: BSD
Conflicts: python-networkx
Provides: python-networkx=2.6rc1.r1.gc444024a5
Submitter: groctel
Maintainer: groctel
Last Packager: groctel
Votes: 1
Popularity: 0.56
First Submitted: 2021-05-03 10:51
Last Updated: 2021-06-01 08:50

Required by (85)

Sources (1)

Latest Comments

bcb commented on 2021-05-10 07:25

For anybody else who was using this to avoid the version conflict with python-decorator, version 2.5.1-2 in the main repositories has been patched so it now works again.

groctel commented on 2021-05-04 20:07

Thank you very much @bcb! I've udpated the PKGBUILD with your version and added a thanks to the commit message <3

bcb commented on 2021-05-04 10:22

Checksum is out of date. Is there any reason this package does not use Git to obtain the sources rather than a constantly changing zip? The following PKGBUILD works for me.

pkgname=python-networkx-git
_name=networkx
pkgver=2.5.r276.g3ccf9200c
pkgrel=1
pkgdesc="Python package for the creation, manipulation, and study of the structure, dynamics, and functions of complex networks."
arch=('any')
url="https://github.com/networkx/networkx"
license=('BSD')
depends=(
    'python-decorator'
    'python-matplotlib'
    'python-numpy'
    'python-pandas'
    'python-scipy'
)
makedepends=('git')
conflicts=('python-networkx')
provides=("python-networkx=$pkgver")
source=("git+$url#branch=main")
sha512sums=('SKIP')

pkgver() {
    cd "$srcdir/$_name"
    git describe --long | sed 's/^networkx-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/$_name"
    sed -i 's/decorator>=4.4,<5/decorator>=5.0.7/' requirements/default.txt
    python setup.py build
}

package() {
    cd "$srcdir/$_name"
    python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
    install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

Note I also added the provides= line so it can be used with python-scikit-image.