Package Details: lua52-luaossl 20200709-1

Git Clone URL: https://aur.archlinux.org/lua-luaossl.git (read-only, click to copy)
Package Base: lua-luaossl
Description: Most comprehensive OpenSSL module in the Lua universe for Lua 5.2
Upstream URL: http://25thandclement.com/~william/projects/luaossl.html
Licenses: MIT
Submitter: daurnimator
Maintainer: daurnimator
Last Packager: daurnimator
Votes: 3
Popularity: 0.119379
First Submitted: 2017-01-28 14:37
Last Updated: 2020-07-09 13:16

Required by (1)

Sources (1)

Latest Comments

jprjr commented on 2020-11-12 21:47

Hi there, now that lua5.4 is in the repos, I want ahead and updated the PKGBUILD to create a lua53 variant.

# Maintainer: Daurnimator <daurnimator@archlinux.org>

pkgname=('lua-luaossl' 'lua51-luaossl' 'lua52-luaossl' 'lua53-luaossl')
pkgver=20200709
pkgrel=2
arch=('x86_64')
url='http://25thandclement.com/~william/projects/luaossl.html'
license=('MIT')
makedepends=('lua' 'lua51' 'lua52' 'lua53')
depends=('openssl')
source=("$pkgname-$pkgver.tar.gz::https://github.com/wahern/luaossl/archive/rel-$pkgver.tar.gz")
md5sums=('3bc2d6f3fc72bf68571f8e21f0acf8c4')

build() {
    cd luaossl-rel-$pkgver;
    make prefix=/usr LUA_APIS="5.1 5.2 5.3 5.4"
}

package_lua-luaossl() {
    pkgdesc='Most comprehensive OpenSSL module in the Lua universe for Lua 5.4'

    cd luaossl-rel-$pkgver;
    make DESTDIR="$pkgdir" prefix=/usr install5.4
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua51-luaossl() {
    pkgdesc='Most comprehensive OpenSSL module in the Lua universe for Lua 5.1'

    cd luaossl-rel-$pkgver;
    make DESTDIR="$pkgdir" prefix=/usr install5.1
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua52-luaossl() {
    pkgdesc='Most comprehensive OpenSSL module in the Lua universe for Lua 5.2'

    cd luaossl-rel-$pkgver;
    make DESTDIR="$pkgdir" prefix=/usr install5.2
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua53-luaossl() {
    pkgdesc='Most comprehensive OpenSSL module in the Lua universe for Lua 5.3'

    cd luaossl-rel-$pkgver;
    make DESTDIR="$pkgdir" prefix=/usr install5.3
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}