Package Details: lokinet 0.7.1-2

Git Clone URL: https://aur.archlinux.org/lokinet.git (read-only, click to copy)
Package Base: lokinet
Description: Anonymous, decentralized and IP based overlay network for the internet.
Upstream URL: https://lokinet.org
Keywords: Anonymity Internet loki-network Network
Licenses: zlib
Submitter: nekgem
Maintainer: nekgem
Last Packager: nekgem
Votes: 2
Popularity: 0.80
First Submitted: 2020-05-06 01:44
Last Updated: 2020-05-15 21:51

Latest Comments

nekgem2 commented on 2020-10-03 04:13

adjusted for updated tarball & some other tweaks

# Maintainer: nekgem2 <nekgem2@firemail.cc>
pkgname=lokinet
pkgver=0.8.0
pkgrel=2
pkgdesc="Anonymous, decentralized and IP based overlay network for the internet."
arch=('x86_64' 'aarch64')
url="https://lokinet.org"
license=('GPL3')
depends=('libuv' 'libsodium' 'curl' 'zeromq' 'unbound' 'sqlite')
makedepends=('git' 'cmake')
install='lokinet.install'
source=("https://i2p.rocks/files/lokinet/archives/$pkgver/lokinet-v$pkgver.tar.xz"{,.sig}
        'lokinet.service'
        'lokinet-bootstrap.service'
        'lokinet-default-config.service'
        'lokinet-resume.service'
        'lokinet.sysusers'
        'lokinet.tmpfiles')
sha256sums=('8eed27bee21bf504d9753b31d0709b59dd268fafcfde9869d773637c8077abf6'
            'SKIP'
            'ce7f40f91c1de020466f82fb504e261e66774ef5f97a9d914dbe61236a1baf01'
            '21c9bc83f8466ab17fa927561d7f24f930f97c996a8aa0fbbbbb2b65cb97b342'
            '6ef779170b72856bbb8df40c34a808acffddd156684bdb66a55e71d50cf95841'
            'bcf4bd7b38d2f054e25cc243353d3c9a56d1948b42ad07ee5c0260de06e8dd6c'
            '137cf7eeebc8737d62f3ccfad2398fb1c442a91cb9db7d650429b218dd949a00'
            '53837c9cfc90b93d55558045108a5d1d7a8b8a75a266af264d7f9101363d043f')
validpgpkeys=('67EF6BA68E7B0B0D6EB4F7D4F357B3B42F6F9B05') # Jeff Becker (probably not evil) <jeff@i2p.rocks>

build() {
    cd "lokinet-v$pkgver"

    rm -rf build && mkdir build && cd build
    # XXX cmake stuff overrides CFLAGS
    cmake \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_C_FLAGS="$CFLAGS" \
        -DCMAKE_CXX_FLAGS="$CXXFLAGS" \
        -DNATIVE_BUILD=OFF \
        -DSTATIC_LINK_RUNTIME=OFF \
        -DUSE_NETNS=OFF \
        -DUSE_AVX2=OFF \
        -DXSAN=OFF \
        -DWITH_TESTS=OFF \
        -DDOWNLOAD_SODIUM=OFF \
        -DSUBMODULE_CHECK=OFF \
        -DWITH_SYSTEMD=ON \
        -Wno-dev \
        ..
    make
}

package() {
    cd "lokinet-v$pkgver"
    install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    cd build
    make DESTDIR="$pkgdir" install

    install -D -m 644 "$srcdir/lokinet.service"                "$pkgdir/usr/lib/systemd/system/lokinet.service"
    install -D -m 644 "$srcdir/lokinet-bootstrap.service"      "$pkgdir/usr/lib/systemd/system/lokinet-bootstrap.service"
    install -D -m 644 "$srcdir/lokinet-default-config.service" "$pkgdir/usr/lib/systemd/system/lokinet-default-config.service"
    install -D -m 644 "$srcdir/lokinet-resume.service"         "$pkgdir/usr/lib/systemd/system/lokinet-resume.service"
    install -D -m 644 "$srcdir/lokinet.sysusers"               "$pkgdir/usr/lib/sysusers.d/lokinet.conf"
    install -D -m 644 "$srcdir/lokinet.tmpfiles"               "$pkgdir/usr/lib/tmpfiles.d/lokinet.conf"
}

nekgem2 commented on 2020-10-02 02:20

preliminary pkgbuild for 0.8.0

# Maintainer: nekgem <nekgem@cock.li>
pkgname=lokinet
pkgver=0.8.0
pkgrel=1
pkgdesc="Anonymous, decentralized and IP based overlay network for the internet."
arch=('x86_64' 'aarch64')
url="https://lokinet.org"
license=('ZLIB')
depends=('libuv' 'libsodium' 'curl' 'unbound')
makedepends=('git' 'cmake')
install='lokinet.install'
_gitname=loki-network
source=("https://i2p.rocks/files/lokinet/archives/$pkgver/lokinet-v$pkgver.tar.xz"
        "https://i2p.rocks/files/lokinet/archives/$pkgver/lokinet-v$pkgver.tar.xz.sig"
        'lokinet.service'
        'lokinet-bootstrap.service'
        'lokinet-default-config.service'
        'lokinet-resume.service'
        'lokinet.sysusers'
        'lokinet.tmpfiles')
sha256sums=('a0e2b99f3a30315edba3b576923d46dc4193e32c6259c979227a3bd61e78344f'
            'SKIP'
            'ce7f40f91c1de020466f82fb504e261e66774ef5f97a9d914dbe61236a1baf01'
            '21c9bc83f8466ab17fa927561d7f24f930f97c996a8aa0fbbbbb2b65cb97b342'
            '6ef779170b72856bbb8df40c34a808acffddd156684bdb66a55e71d50cf95841'
            'bcf4bd7b38d2f054e25cc243353d3c9a56d1948b42ad07ee5c0260de06e8dd6c'
            '137cf7eeebc8737d62f3ccfad2398fb1c442a91cb9db7d650429b218dd949a00'
            '53837c9cfc90b93d55558045108a5d1d7a8b8a75a266af264d7f9101363d043f')

build() {
    cd "lokinet-v$pkgver"

    rm -rf build && mkdir build && cd build
    # XXX cmake stuff overrides CFLAGS
    cmake \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_C_FLAGS="$CFLAGS" \
        -DCMAKE_CXX_FLAGS="$CXXFLAGS" \
        -DNATIVE_BUILD=OFF \
        -DSTATIC_LINK_RUNTIME=OFF \
        -DUSE_NETNS=OFF \
        -DUSE_AVX2=OFF \
        -DXSAN=OFF \
        -DWITH_SHARED=OFF \
        -DWITH_TESTS=OFF \
        -DDOWNLOAD_SODIUM=OFF \
        -DSUBMODULE_CHECK=OFF \
        -Wno-dev \
        ..
    make
}

package() {
    cd "lokinet-v$pkgver"
    install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
    cd build
    make DESTDIR="$pkgdir" install

    install -D -m 644 "$srcdir/lokinet.service"                "$pkgdir/usr/lib/systemd/system/lokinet.service"
    install -D -m 644 "$srcdir/lokinet-bootstrap.service"      "$pkgdir/usr/lib/systemd/system/lokinet-bootstrap.service"
    install -D -m 644 "$srcdir/lokinet-default-config.service" "$pkgdir/usr/lib/systemd/system/lokinet-default-config.service"
    install -D -m 644 "$srcdir/lokinet-resume.service"         "$pkgdir/usr/lib/systemd/system/lokinet-resume.service"
    install -D -m 644 "$srcdir/lokinet.sysusers"               "$pkgdir/usr/lib/sysusers.d/lokinet.conf"
    install -D -m 644 "$srcdir/lokinet.tmpfiles"               "$pkgdir/usr/lib/tmpfiles.d/lokinet.conf"
}