Package Details: libindi-asi 1.8.5-1

Git Clone URL: https://aur.archlinux.org/libindi-asi.git (read-only, click to copy)
Package Base: libindi-asi
Description: 3rd party drivers for INDI, support for ZWO devices: ASI cameras, EFW filter wheel, ASI ST4 port and ASI focuser
Upstream URL: http://www.indilib.org/index.php?title=Main_Page
Licenses: LGPL2.1
Submitter: sebo_b
Maintainer: sebo_b
Last Packager: sebo_b
Votes: 1
Popularity: 0.58
First Submitted: 2019-05-27 22:04
Last Updated: 2020-05-10 13:28

Dependencies (3)

Required by (0)

Sources (1)

Latest Comments

yorickpeterse commented on 2020-05-10 16:31

I gave the new libindi-asi and libasi packages a try and they work perfectly, thanks!

sebo_b commented on 2020-05-10 13:31

libindi recently split 3rdparty drivers from the main repository, also there seems to be some changes in libindi-asi driver, as it now requires separate asi sdk.

Anyway I have updated the package, so it should work now. However you need to install libasi, which I have also created.

yorickpeterse commented on 2020-05-09 00:15

I finally managed to get things working, though it required a bit of a weird setup; suggesting I probably overlooked something. I ended up creating two PKGBUILD files:

  1. One PKGBUILD to build just the libasi library
  2. One PKGBUILD to build just the libasi drivers/executables

For the library, I used this PKGBUILD:

pkgname=libindi-libasi
pkgver=1.8.5
pkgrel=1
pkgdesc="3rd party library for INDI, support for ZWO devices: ASI cameras, EFW filter wheel, ASI ST4 port and ASI focuser"
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(i686 x86_64)
depends=(libindi)
conflicts=(libindi-asi)
makedepends=(cmake)
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=('acbddca69c25b2c46ebc0982e8dbbf4912a43f6a4b45d46b007deab8805caed8')

prepare() {
  mkdir -p build

  cd indi-3rdparty-${pkgver}

  # Disable all libraries except libasi
  sed -i -e '/option(WITH_.*On/s/ On/ Off/' CMakeLists.txt
}

build() {
  cd build

  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DWITH_ASICAM=On \
    ../indi-3rdparty-${pkgver}

  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}

For the driver executables I used this PKGBUILD:

pkgname=libindi-asi-driver
pkgver=1.8.5
pkgrel=1
pkgdesc="3rd party drivers for INDI, support for ZWO devices: ASI cameras, EFW filter wheel, ASI ST4 port and ASI focuser"
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(i686 x86_64)
depends=(libindi-libasi)
conflicts=(libindi-asi)
makedepends=(cmake)
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=('acbddca69c25b2c46ebc0982e8dbbf4912a43f6a4b45d46b007deab8805caed8')

prepare() {
  mkdir -p build
}

build() {
  cd build

  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    ../indi-3rdparty-${pkgver}/indi-asi

  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}

I couldn't get this done using a single PKGBUILD as compiling the drivers will fail unless libasi is already present. Maybe there is a way of telling CMake to search for the library in the build chroot, but it's already midnight and I couldn't figure this out.

Hopefully this is of any use to those trying to build the drivers.

yorickpeterse commented on 2020-05-08 20:11

I got the ASI drivers to build using the following PKGBUILD:

# Maintainer: Sebastian Baberowski <sebastian@baberowski.com>

pkgname=libindi-asi
pkgver=1.8.5
pkgrel=1
pkgdesc="3rd party drivers for INDI, support for ZWO devices: ASI cameras, EFW filter wheel, ASI ST4 port and ASI focuser"
url="http://www.indilib.org/index.php?title=Main_Page"
license=(LGPL2.1)
arch=(i686 x86_64)
depends=(libindi)
makedepends=(cmake)
source=("https://github.com/indilib/indi-3rdparty/archive/v${pkgver}.tar.gz")
sha256sums=('acbddca69c25b2c46ebc0982e8dbbf4912a43f6a4b45d46b007deab8805caed8')

prepare() {
  mkdir -p build
  cd indi-3rdparty-${pkgver}

  #set all to off by default
  sed -i -e '/option(WITH_.*On/s/ On/ Off/' CMakeLists.txt
}

build() {
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DUDEVRULES_INSTALL_DIR=/usr/lib/udev/rules.d \
    -DWITH_ASICAM=On \
    ../indi-3rdparty-${pkgver}
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}

Unfortunately, this does not appear to build/install the necessary driver executables; not sure yet why that is.

yorickpeterse commented on 2020-05-08 17:38

3rd party drivers have been moved to a separate repository: https://github.com/indilib/indi-3rdparty