Package Details: higan-git 110.r0.g483c5781-1

Git Clone URL: https://aur.archlinux.org/higan-git.git (read-only, click to copy)
Package Base: higan-git
Description: Nintendo multi-system emulator by Byuu
Upstream URL: https://higan.byuu.org/
Licenses: GPL3
Conflicts: higan
Provides: higan
Submitter: darkfm
Maintainer: FabioLolix
Last Packager: FabioLolix
Votes: 2
Popularity: 0.000004
First Submitted: 2017-06-04 11:22
Last Updated: 2020-07-03 20:25

Latest Comments

E3LDDfrK commented on 2020-03-12 17:24

Honestly, it's hard to use. The manual doesn't do a good job. And the interface is different to the community's higan package.

noabody commented on 2019-11-18 07:10

Proof of concept to build current Higan/Byuu code since the main project concluded.

# Maintainer: ???

pkgbase=higan
_pkgname=byuu
pkgname=("$pkgbase" "$_pkgname")
pkgver=115.r43.g54e8c7c2a
pkgrel=1
url='https://byuu.org'
arch=(x86_64)
license=(GPL3)
depends=(gtksourceview2 libao libgl libpulse libxv openal sdl2)
makedepends=(git mesa)
options=(!emptydirs)
source=(git+https://github.com/"$pkgbase"-emu/"$pkgbase")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgbase"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$pkgbase"
  for _sub in "$pkgbase"-ui "$_pkgname" icarus; do
    make -C $_sub clean platform=linux
  done
}

build() {
  cd "$pkgbase"
  for _sub in "$pkgbase"-ui "$_pkgname" icarus; do
    make -C $_sub -j4 platform=linux
  done
}

package_higan() {
  pkgdesc='Nintendo multi-system emulator by Byuu'
  provides=("$pkgbase")
  conflicts=("$pkgbase" "$pkgbase"-git)
  replaces=("$pkgbase"-git)
  cd "$pkgbase"
  install -Dm 755 "$pkgbase"-ui/out/"$pkgbase"-ui -t "$pkgdir"/usr/bin/
  install -Dm 644 "$pkgbase"-ui/resource/"$pkgbase"-ui.desktop -t "$pkgdir"/usr/share/applications/
  install -Dm 644 "$pkgbase"-ui/resource/"$pkgbase"-ui.png -t "$pkgdir"/usr/share/pixmaps/
  cp -dr --no-preserve='ownership' "$pkgbase"/System "$pkgdir"/usr/share/"$pkgbase"
  install -Dm 644 extras/"$pkgbase"/* -t "$pkgdir"/usr/share/"$pkgbase"/
  install -Dm 755 icarus/out/icarus -t "$pkgdir"/usr/bin/
  install -Dm 644 icarus/resource/icarus.desktop -t "$pkgdir"/usr/share/applications/
  install -Dm 644 icarus/resource/icarus.png -t "$pkgdir"/usr/share/pixmaps/
  install -dm 755 "$pkgdir"/usr/share/icarus
  cp -dr --no-preserve='ownership' icarus/Database "$pkgdir"/usr/share/icarus/
  cp -dr --no-preserve='ownership' icarus/Firmware "$pkgdir"/usr/share/icarus/
  find "$pkgdir"/usr/share/"$pkgbase" -type f -iname .gitignore -delete
}

package_byuu() {
  pkgdesc='Optimized multi-system emulator based on Higan core.'
  provides=("$_pkgname")
  conflicts=("$_pkgname" "$_pkgname"-git)
  replaces=("$_pkgname"-git)
  cd "$pkgbase"
  install -Dm 755 "$_pkgname"/out/"$_pkgname" -t "$pkgdir"/usr/bin/
  install -Dm 644 "$_pkgname"/resource/"$_pkgname".desktop -t "$pkgdir"/usr/share/applications/
  install -Dm 644 "$_pkgname"/resource/"$_pkgname".png -t "$pkgdir"/usr/share/pixmaps/
  install -dm 755 "$pkgdir"/usr/share/"$_pkgname"
  install -Dm 644 extras/"$_pkgname"/* -t "$pkgdir"/usr/share/"$_pkgname"/
  find "$pkgdir"/usr/share/"$_pkgname" -type f -iname .gitignore -delete
}