summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 749f71e67ce2429b9243cb799b6982ab7b223d7f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# $Id$
# Maintainer: Silvio Fricke <silvio.fricke@gmail.com>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Kevin Piche <kevin@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

_pkgname=zim
pkgname=${_pkgname}-git
pkgver=0.72.0.r2.8514c6b0
pkgrel=1
pkgdesc="A WYSIWYG text editor that aims at bringing the concept of a wiki to the desktop. Git Version"
arch=(any)
license=('GPL' 'PerlArtistic')
url="http://zim-wiki.org/"
depends=('python')
conflicts=('zim')
replaces=('zim')
optdepends=('bzr: Version Control plugin'
            'ditaa: Insert Ditaa plugin'
            'git: Version Control plugin'
            'gnuplot: Insert Gnuplot plugin'
            'graphviz: Insert Diagram & Link Map plugins'
            'hicolor-icon-theme: hicolor theme hierarchy'
            'lilypond: Insert Score plugin'
            'mercurial: Version Control plugin'
            'pygtksourceview2: Source View plugin'
            'python-gtkspell: Spell Checker plugin'
            'r: Insert GNU R Plot plugin'
            'scrot: Insert Screenshot plugin'
            'texlive-bin: Insert Equation plugin'
            'zeitgeist: Log events with Zeitgeist plugin'
)

source=('zim-git::git+https://github.com/jaap-karssenberg/zim-desktop-wiki.git')
md5sums=('SKIP')

pkgver() {
	cd ${srcdir}/${pkgname}
	printf "%s" "$(git describe --tags --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

build() {
	cd ${srcdir}/${pkgname}

	sed -i 's|\t\tinstall_class.run(self)|&\n\t\treturn None|' setup.py
}

package() {
	cd ${srcdir}/${pkgname}

	python setup.py install --root=${pkgdir} --optimize=1
}