summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d210edf4100fe56e434169117fde77d871b40c36 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Moritz Lipp <mlq@pwmt.org>

pkgname=zathura-djvu-git
pkgrel=1
pkgver=0.2.9.2.g12ef085
pkgdesc="DjVu support for zathura"
arch=('i686' 'x86_64')
url="http://pwmt.org/projects/zathura/plugins/zathura-djvu"
license=('custom')
depends=('zathura-git' 'djvulibre')
makedepends=('git' 'python-sphinx' 'intltool' 'meson')
checkdepends=('check')
conflicts=('zathura-djvu')
provides=('zathura-djvu')
source=('zathura-djvu::git+https://git.pwmt.org/pwmt/zathura-djvu.git#branch=develop')
md5sums=('SKIP')
_gitname=zathura-djvu

prepare() {
  mkdir -p build
}

build() {
  cd build
  meson --prefix=/usr --buildtype=release $srcdir/$_gitname
  ninja
}

check() {
  cd build
  ninja test
}

package() {
  cd build
  DESTDIR="$pkgdir/" ninja install
}

pkgver() {
  cd "$_gitname"
  local ver="$(git describe --long)"
  printf "%s" "${ver//-/.}"
}

# vim:set ts=2 sw=2 et: