summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3580148688b818ef8931c8a468e2775eccf02c26 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: CrocoDuck <crocoduck dot oducks at gmail dot com>
# Contributor: Haskellfant <moritz.kiefer@purelyfunctional.org

pkgname=zam-plugins-git
pkgver=3.10.r43.g2639251
pkgrel=1
pkgdesc="Collection of LV2/LADSPA/VST audio plugins for high quality processing."
arch=('i686' 'x86_64')
url="https://github.com/zamaudio/zam-plugins"
license=('GPL2')
provides=(${pkgname%-*})
conflicts=(${pkgname%-*} 'zamplugins')
depends=('jack2' 'libglvnd' 'fftw' 'libsamplerate')
makedepends=('git' 'pkg-config' 'libx11' 'libgl' 'liblo' 'jack' 'ladspa')
source=("${pkgname%-*}"::'git+https://github.com/zamaudio/zam-plugins.git'
        'git+https://github.com/DISTRHO/DPF.git')
md5sums=('SKIP'
         'SKIP')
         
pkgver() {
  cd "${pkgname%-*}"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${pkgname%-*}"
  git submodule init
  git config submodule.dpf.url "${srcdir}/DPF"
  git submodule update
}

build() {
  cd "${pkgname%-*}"
  make
}

package() {
  cd "${pkgname%-*}"
  make DESTDIR="$pkgdir/" PREFIX=/usr install
}