summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1070d754d4f01f961fc6374814dfd7e7abf55807 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Mark Wagie <mark.wagie at tutanota dot com>
# Contributor: toluschr <toluschr at protonmail dot com>
pkgname=('yaru-colors-gtk-theme-git'
         'yaru-colors-icon-theme-git'
         'yaru-colors-wallpapers-git')
pkgbase='yaru-colors-gtk-theme-git'
pkgver=2.0.r13.g3ac6559
pkgrel=2
pkgdesc="A fork of Ubuntu's Yaru theme - in different colors"
arch=('any')
license=('GPL3')
url="https://github.com/Jannomag/Yaru-Colors"
makedepends=('git')
options=('!strip')
source=('git+https://github.com/Jannomag/Yaru-Colors.git')
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/Yaru-Colors"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

package_yaru-colors-gtk-theme-git() {
	depends=('gtk3' 'gdk-pixbuf2' 'gtk-engine-murrine' 'gnome-themes-extra')
	optdepends=('yaru-colors-wallpapers' 'yaru-colors-icon-theme' 'yaru-sound-theme')
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "$srcdir/Yaru-Colors"
	install -d "$pkgdir/usr/share/themes"
	cp -a Themes/* "$pkgdir/usr/share/themes"
}

package_yaru-colors-icon-theme-git() {
	depends=('hicolor-icon-theme' 'gtk-update-icon-cache' 'librsvg' 'humanity-icon-theme')
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "$srcdir/Yaru-Colors"
	install -d "$pkgdir/usr/share/icons"
	cp -a Icons/* "$pkgdir/usr/share/icons"
}

package_yaru-colors-wallpapers-git() {
	provides=("${pkgname%-git}")
	conflicts=("${pkgname%-git}")

	cd "$srcdir/Yaru-Colors"
	install -d "$pkgdir/usr/share/backgrounds/yaru-colors"
	cp -a Wallpapers/* "$pkgdir/usr/share/backgrounds/yaru-colors"
}