summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: dde169037124749fd55306e334f895f8a42ef4dc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
# Maintainer: Andrey Vihrov <andrey.vihrov at gmail.com>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Lex Black <autumn-wind at web dot de>
# Contributor: cute.tec@gmail.com

pkgname=xfwm4-git
pkgver=4.12.0.r237.g03c4b509
pkgrel=1
pkgdesc='Xfce window manager - git checkout'
arch=('i686' 'x86_64')
license=('GPL2')
url='http://git.xfce.org/xfce/xfwm4'
groups=('xfce4')
depends=('libxfce4ui' 'libwnck' 'libxpresent')
makedepends=('git' 'intltool' 'xfce4-dev-tools' 'exo')
provides=('xfwm4')
conflicts=('xfwm4')
source=('git://git.xfce.org/xfce/xfwm4')
sha256sums=('SKIP')

pkgver() {
	cd xfwm4/

	if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
		printf '%s.r%s.g%s' \
			"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
			"$(git rev-list --count ${GITTAG}..)" \
			"$(git log -1 --format='%h')"
	else
		printf '0.r%s.g%s' \
			"$(git rev-list --count master)" \
			"$(git log -1 --format='%h')"
	fi
}

prepare() {
	cd xfwm4

	# https://bugzilla.xfce.org/show_bug.cgi?id=12534
	git revert --no-commit 0dfb55407a830572f03297b3c118fac1f3c5b80d
}

build() {
	cd xfwm4/

	./autogen.sh
	./configure \
		--enable-maintainer-mode \
		--prefix=/usr \
		--sysconfdir=/etc \
		--libexecdir=/usr/lib \
		--localstatedir=/var \
		--disable-static \
		--enable-startup-notification \
		--enable-render \
		--enable-randr \
		--enable-epoxy \
		--enable-xpresent \
		--enable-compositor \
		--enable-xsync \
		--disable-debug
	make
}

package() {
	cd xfwm4/

	make DESTDIR=${pkgdir} install
}