summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c6d4b3b20bdc465bf9144ab36816713b9077e755 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer PumpkinCheshire <sollyonzou@gmail.com>
# Maintainer: robertfoster

pkgname=whatweb-git
_name=whatweb
pkgver=0.5.5.r0.1b351697
pkgrel=1
pkgdesc="Next generation web scanner that identifies what websites are running."
arch=('i686' 'x86_64')
replaces=('whatweb')
conflicts=('whatweb')
provides=('whatweb')
url="http://www.morningstarsecurity.com/research/whatweb"
license=('GPL')
depends=('ruby' 'ruby-addressable')
optdepends=('ruby-rake: development test use'
           'ruby-rdoc: development test use'
           'ruby-minitest: development test use'
           'ruby-rubocop: development test use'
           'ruby-bundler-audit: development test use'
           'ruby-pry: debugging')
source=("whatweb::git://github.com/urbanadventurer/WhatWeb.git")
md5sums=('SKIP')

prepare() {
    cd $_name
    sed -i '/bundle install/d' Makefile
    sed -i "s|require 'lib/whatweb'|require '/usr/share/whatweb/lib/whatweb'|" whatweb
}

package() {
	cd $_name
	make DESTDIR=$pkgdir install
}

pkgver() {
	cd $_name
	printf "%s" "$(git describe --tags --long | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g')"
}