summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: e8802752730db845f8ad3c2110536fef85883fb6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Clint Valentine <valentine.clint@gmail.com>
# Contributer: Grey Christoforo <first name [at] last name [dot] net>

pkgname=ucsc-kent-genome-tools
pkgver=394
pkgrel=1
pkgdesc="UCSC Kent bioinformatics utilities: kent source utilities"
arch=('x86_64')
url="http://hgdownload.soe.ucsc.edu/admin/exe/"
license=('custom:UCSC')
install="${pkgname}".install
depends=('libpng' 'mariadb-clients' 'uuid' 'openssl')
source=(
  .hg.conf
  "${pkgname}".sh
  "${pkgname}"-"${pkgver}".src.tgz::http://hgdownload.soe.ucsc.edu/admin/exe/userApps.v"${pkgver}".src.tgz
)
sha256sums=('359db5b022847d3d674f21821fa08a363d2183379d59a2b63129fcf90954d674'
            '5ccec9d5e4de9be22746fab1591127b61176c8c4d586c0dd1df13ee5e52a5367'
            'e5756cb332c172cf589ba449c99d36d370c826bce3be9a546090bdfdefcab330')

prepare() {
  cd "${srcdir}"/userApps
  make clean
}

build() {
  cd "${srcdir}"/userApps
  make all
}

package() {
  install -Dm644 .hg.conf "${pkgdir}"/opt/"${pkgname}"/.hg.conf
  install -Dm755 "${pkgname}".sh  "${pkgdir}"/etc/profile.d/"${pkgname}".sh

  for script in "${srcdir}"/userApps/bin/*; do
    install -Dm755 "${script}" "${pkgdir}"/opt/"${pkgname}"/$(basename "${script}")
  done

  install -Dm644 "${srcdir}"/userApps/README "${pkgdir}"/usr/share/doc/"${pkgname}"/README
  install -Dm644 "${srcdir}"/userApps/kentUtils.Documentation.txt "${pkgdir}"/usr/share/doc/"${pkgname}"/kentUtils.Documentation.txt

  install -Dm644 "${srcdir}"/userApps/licenseUcscGenomeBrowser.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/licenseUcscGenomeBrowser.txt
  install -Dm644 "${srcdir}"/userApps/GenomeBrowserLicense.pdf "${pkgdir}"/usr/share/licenses/"${pkgname}"/GenomeBrowserLicense.pdf
  install -Dm644 "${srcdir}"/userApps/licenseBlat.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/licenseBlat.txt
}