summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d91d1c8476e2b38e583007739b24ac2ca80605ce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Jose Riha <jose1711 gmail com>

pkgname=tunneler-git
_pkgname=tunneler
pkgver=r2.cd75602
pkgrel=1
pkgdesc="port of an old DOS game written using SDL"
url="https://github.com/jose1711/tunneler"
depends=('sdl')
makedepends=('git' 'gendesk')
conflicts=(tunneler)
license=('GPL')
arch=('x86_64' 'i686')
source=("${pkgname}"::'git+https://github.com/jose1711/tunneler.git')
md5sums=('SKIP')

prepare() {
  gendesk -f -n --pkgname "${_pkgname}" --pkgdesc "${pkgdesc}" --exec "tunneler" --categories "Games"
}

pkgver() {
  cd "${srcdir}/${pkgname}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd ${srcdir}/${pkgname}
  aclocal
  automake --add-missing
  autoconf
  ./configure --prefix=/usr
  make
}

package() {
  cd ${srcdir}/${pkgname}
  make DESTDIR=${pkgdir} install
  install -Dm644 "${srcdir}/${_pkgname}.desktop" "$pkgdir/usr/share/applications/${_pkgname}.desktop"
}

# vim:set ts=2 sw=2 et: