summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b42e2b8672bb33ca6ceb1f925b4300b2442338f8 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Chris Cromer <chris@cromer.cl>

pkgname=tuf-manager
pkgver=1.2.2
pkgrel=2
pkgdesc="Program to control ASUS TUF laptop keyboard lighting and fan modes"
arch=("x86_64")
url="https://git.cromer.cl/cromer/tuf-manager"
license=("BSD3")
depends=("gtk3>=3.14" "glib2" "dbus-glib" "libnotify" "libappindicator-gtk3" "polkit"  "faustus-rublag-dkms-git")
makedepends=("meson" "ninja" "vala")
source=("https://git.cromer.cl/cromer/${pkgname}/archive/${pkgver}.tar.gz")
sha512sums=('7e11f616770586db414d8c96c20a53f0d09f9a3b12cbea305f4a68d5d33d8fda8c509c5e584487c63b693e353f06b815193c0dbf73a86a4b68f498f555659089')

prepare() {
	[ -d "${srcdir}"/build ] && rm -rf build
	mkdir "${srcdir}"/build
}

build() {
	cd "${srcdir}"/build
	meson "${srcdir}/${pkgname}" \
		--prefix=/usr \
		--libexecdir=/usr/lib
	ninja
}

package() {
	cd "${srcdir}"/build
	DESTDIR="${pkgdir}" ninja install
	rm "${pkgdir}"/usr/share/glib-2.0/schemas/gschemas.compiled
}