summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: de41cebea6e7af387ab10677a89000d03a31a508 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
# Maintainer: Allen Zhong <moeallenz@gmail.com>
# Contributor: Felix Yan <felixonmars@gmail.com>

pkgname=tsar-git
_gitname=tsar
pkgver=0.404.14c1392
pkgrel=1
pkgdesc="Taobao System Activity Reporter"
arch=('x86_64')
url="http://tsar.taobao.org/"
license=('Apache')
depends=('glibc' 'luajit' 'cron')
makedepends=('git')
backup=('etc/tsar/tsar.conf')
source=("git://github.com/alibaba/$_gitname.git"
        "fix_module_path.patch"
        "fix_apache_log.patch")
sha1sums=('SKIP'
          '64f0e29f56e2be08a54ecd6b1819e1c0f97e72cb'
          '3ad26fcbc9bcbb886caa58e3315eb02edb65534f')

pkgver() {
  cd "$srcdir/$_gitname"
  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
}

build() {
  cd "$srcdir/${_gitname}"
  patch -Np1 -i "$srcdir"/fix_module_path.patch
  patch -Np1 -i "$srcdir"/fix_apache_log.patch
  make  # --prefix=/usr Not supported, WTF
}

package() {
  cd "$srcdir/${_gitname}"

  install -d "$pkgdir"/usr/lib/tsar/modules
  cp modules/*.so "$pkgdir"/usr/lib/tsar/modules/

  install -Dm755 src/tsar "$pkgdir"/usr/bin/tsar

  install -Dm644 conf/tsar.conf "$pkgdir"/etc/tsar/tsar.conf
  install -Dm644 conf/tsar.logrotate "$pkgdir"/etc/logrotate.d/tsar
  install -Dm644 conf/tsar.cron "$pkgdir"/etc/cron.d/tsar

  install -Dm644 conf/tsar.8 "$pkgdir"/usr/share/man/man8/tsar.8
}