summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 308ba17af91fc93910c82a184b364424024d1794 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: SanskritFritz (gmail)

_pkgname=timekpr
pkgname=$_pkgname-next
pkgver=0.3.7
pkgrel=1
pkgdesc="Control the computer usage of users. You can limit daily usage based on a timed access duration and configure periods of day when they can log in."
arch=('any')
url='https://launchpad.net/timekpr-next'
license=('GPL')
depends=('python-gobject' 'gtk3>=3.4' 'polkit' 'python-dbus' 'python-gobject' 'libappindicator-gtk3' 'dbus>=1.10.1' 'python-psutil')
optdepends=('lxqt-policykit: to start the Control Panel like in LXQT'
            'mate-polkit: to start the Control Panel like in Mate'
            'polkit-kde-agent: to start the Control Panel like in Plasma'
            'polkit-gnome: to start the Control Panel like in Gnome (legacy)'
            'xfce-polkit: to start the Control Panel like in XFCE')
provides=('timekpr')
conflicts=('timekpr' 'timekpr-next-beta' 'timekpr-beta' 'timekpr-revived-bzr' 'timekpr-next-git')
source=("https://launchpad.net/timekpr-next/stable/$pkgver/+download/timekpr-next-$pkgver.tar.gz")
install='timekpr-next.install'
md5sums=('406e37ec2d7fc13f63f9e02cc0412a3e')

package() {
	cd "$pkgname"

	cat debian/install | while read a b; do
		case "$a" in
			*"#"*) ;;
			"") ;;
			*)
			f=`basename "$a"`
			if [ -d $a ]; then
				install -d "$pkgdir/$b/$f"
			else
				install -D "$a" "$pkgdir/$b/$f"
			fi
		esac
	done
	install -m755 debian/postrm "$pkgdir"/usr/bin/timekpr.postrm
	install -m755 debian/postinst "$pkgdir"/usr/bin/timekpr.postinst

}