summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 90fec3f90f37f598a1a1100df91d2d1299dac659 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Steffen Weber <-boenki-gmx-de->
# Contributor: Dan Serban
# Contributor: Henrik Olsson

pkgname=sunflower
_pkgver=0.4-62
pkgver=${_pkgver//-/.}
pkgrel=5
pkgdesc="Small and highly customizable twin-panel file manager for Linux with support for plugins"
arch=(any)
license=(GPL3)
url="https://sunflower-fm.org"
depends=(gtk3 vte3 python-gobject python-chardet python-cairo librsvg)
makedepends=(libnotify)
optdepends=('libnotify'
            'python-mutagen: audio-metadata support'
            'gvfs: mount-management')
source=("https://github.com/MeanEYE/Sunflower/releases/download/0.4-62/sunflower-${_pkgver}.tgz")
sha256sums=('f2c47e58efb460f18b4bbaf839a9765ac0e2ae1805d7cbd04b3e345d2d74e900')

build() {
  cd "${srcdir}/Sunflower"
  python setup.py build
}

package() {
  cd "${srcdir}/Sunflower"
  _pyver=$(python -c "from sys import version_info; print(\"%d.%d\" % (version_info[0],version_info[1]))")

  python setup.py install --root="$pkgdir/" --optimize=1  --skip-build
  install -Dm644 images/sunflower.svg "${pkgdir}"/usr/lib/python${_pyver}/site-packages/images/sunflower.svg
  install -Dm644 images/sunflower.png "${pkgdir}/usr/share/pixmaps/sunflower.png"
  rm -rd "${pkgdir}/usr/images"
  cp -r "${srcdir}"/Sunflower/translations/ "${pkgdir}/usr/share/locale"
}