summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 852f12dfe7679790ef19ddd988fa2ad59f74542b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Farouk Mokhtari <faroukmokh@gmail.com>
pkgname=st-duncan-git
_pkgname=st-duncan
pkgver=0.8.2
pkgrel=1
pkgdesc="Simple terminal for X patched with some features"
arch=('i686' 'x86_64')
url="https://github.com/duncan-f/st.git"
license=('MIT')
depends=('libxft')
makedepends=('libxext' 'ncurses' 'git')
provides=('st')
conflicts=('st')
options=('zipman')
source=("${_pkgname}::git+$url")
md5sums=('SKIP')

pkgver() {
  cd "${_pkgname}"
  _pkgver=$(awk '/VERSION/ {print $3}' config.mk|head -1)
  echo "${_pkgver}.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${_pkgname}"
  # skip terminfo which conflicts with nsurses
  sed -i '/tic /d' Makefile
}

build() {
  cd "${_pkgname}"
  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}

package() {
  cd "${_pkgname}"
  make PREFIX=/usr DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
}