summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2d204927de9c1f62f6dc5f25db62d09d617cc0aa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: willemw <willemw12@gmail.com>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: dorphell <dorphell@archlinux.org>
# Contributor: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Sven Schulz <omee@archlinux.de>

pkgname=ssldump
pkgver=0.9b3
pkgrel=15
pkgdesc="SSLv3/TLS network protocol analyzer (from 2002)"
url="http://ssldump.sourceforge.net/"
license=('custom')
arch=('x86_64')
depends=('libpcap' 'openssl')
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz
        $pkgname-$pkgver.tar.gz.asc
        openssl-0.9.8.patch)
sha512sums=('ea81558a243950ab43354c9f33c0a4feae0ae859bc2bd6e6b58838a01f4a1e7a6447f2a9ab1fa40bbe8dbd6c3630c489c17fc9c066cacfddfb64269b0cd5090a'
            'SKIP'
            '21be9134e64d57434e13f4ccf072f1a52f874ce326051fa00f243ad7de8ceec4f0b3d6291cf06749c367c2120ae4c131f940cb994d05232245af0ce040102428')
validpgpkeys=('465E8A2B9258E9CACE651DC3DE7F04469508CFA7')

prepare() {
  cd $pkgname-$pkgver
  patch -Np0 -i ../openssl-0.9.8.patch
  sed -i 's/libpcap.a/libpcap.so/g' configure
  sed -i 's/BINDIR=@sbindir@/BINDIR=@bindir@/' Makefile.in
}

build() {
  cd $pkgname-$pkgver
  # Arch64 fixes --build/host
  ./configure --prefix=/usr \
              --mandir='${prefix}/share/man' \
              --build=i686-pc-linux-gnu \
              --host=i686-pc-linux-gnu
  make
}

package() {
  cd $pkgname-$pkgver
  make prefix="$pkgdir/usr" install
  install -D -m644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}