summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 72002d6ff2a19d2b2081b1bf113cdb33b979d8bc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Philip Goto <philip.goto@gmail.com>

pkgname=shortwave-git
pkgver=r244.ee8b98a
pkgrel=1
pkgdesc="Find and listen to internet radio stations"
arch=(i686 x86_64 armv6h armv7h)
url="https://gitlab.gnome.org/World/Shortwave"
license=(GPL3)
depends=(gstreamer
         libhandy)
makedepends=(cargo
             git
             gobject-introspection
             gst-plugins-base-libs
             libdazzle
             libhandy
             meson
             rust)
provides=(shortwave)
conflicts=(shortwave)
source=("git+https://gitlab.gnome.org/World/Shortwave.git")
sha256sums=('SKIP')

pkgver() {
  cd Shortwave
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  arch-meson Shortwave build
  ninja -C build
}

check() {
  ninja -C build test
}

package() {
  DESTDIR="$pkgdir/" ninja -C build install
}