summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: cd01425dae21f0450afe68ac448893c688590581 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Philip Goto <philip.goto@gmail.com>
# Co-Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>

pkgname=shortwave-git
pkgver=1.0.1.r21.gf38f79b
pkgrel=1
pkgdesc="Find and listen to internet radio stations"
arch=('i686' 'x86_64' 'armv7h' 'aarch64')
url="https://gitlab.gnome.org/World/Shortwave"
license=('GPL3')
depends=('gst-plugins-bad'
         'libhandy')
makedepends=('appstream-glib'
             'git'
             'gobject-introspection'
             'libdazzle'
             'meson'
             'rust'
             'xorgproto')
provides=('shortwave')
conflicts=('shortwave')
source=('git+https://gitlab.gnome.org/World/Shortwave.git')
sha256sums=('SKIP')

pkgver() {
  cd Shortwave
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson Shortwave build
  ninja -C build
}

check() {
  ninja -C build test
}

package() {
  DESTDIR="$pkgdir/" ninja -C build install
}