summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: fb04be7ce0a7feaaa5489fccbdf2c88858a4e26d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# Maintainer: Philip Goto <philip.goto@gmail.com>
# Co-Maintainer: Mark Wagie <yochanan dot marqos at gmail dot com>

pkgname=shortwave-git
pkgver=0.0.1.r0.gcd80fc2
pkgrel=1
pkgdesc="Find and listen to internet radio stations"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://gitlab.gnome.org/World/Shortwave"
license=('GPL3')
depends=('gstreamer'
         'libhandy')
makedepends=('appstream-glib'
             'git'
             'gobject-introspection'
             'gst-plugins-base-libs'
             'libdazzle'
             'meson'
             'rust')
provides=('shortwave' 'gradio')
conflicts=('shortwave' 'gradio')
source=('git+https://gitlab.gnome.org/World/Shortwave.git')
sha256sums=('SKIP')

pkgver() {
  cd Shortwave
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson Shortwave build
  ninja -C build
}

check() {
  ninja -C build test
}

package() {
  DESTDIR="$pkgdir/" ninja -C build install
}