summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3106f717a445f3534e572e491e4b2adb380d908b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Frank Seifferth <frankseifferth@posteo.net>
# Maintainer: MithicSpirit <rpc01234 at gmail dot com>
# Contributor: Rhinoceros <https://aur.archlinux.org/account/rhinoceros>

pkgname=sc-im-git
pkgver=latest
pkgrel=2
pkgdesc='A spreadsheet program based on SC'
arch=('i686' 'x86_64' 'armv7h')
url='https://github.com/andmarti1424/sc-im'
depends=(libxml2 libzip)
optdepends=('libxlsxwriter: export to xlsx. Requires rebuild of sc-im'
            'gnuplot: create graphs')
license=('BSD')
conflicts=('scim-spreadsheet' 'sc-im')
source=('git://github.com/andmarti1424/sc-im'
        'arch.patch')
md5sums=('SKIP'
         '1fbfee20dfb2f3150bd9b20748a9cca1')

prepare() {
  cd "$srcdir/sc-im/src"
  # install things in the correct place for package managers
  patch < "$srcdir/arch.patch"
}

pkgver() {
  cd "$srcdir/sc-im/"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

build() {
  cd "$srcdir/sc-im/src"
  CFLAGS+=' -fcommon '
  make
}

package() {
  cd "sc-im/src"
  make DESTDIR="$pkgdir" install

  install -D -m644 ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}