summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4b96e3a66ef6d1ed64db40e410a62aaeeafd00d0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: mentallaxative <laxatives@gmail.com>

pkgname=rubyroom
pkgver=0.4
pkgrel=4
pkgdesc='Ruby clone of the Whiteroom full-screen text editor'
arch=('x86_64' 'i686')
url='http://rubyroom.rubyforge.org/'
license=('GPL2')
depends=('ruby-gtk2')
makedepends=('imagemagick' 'gendesk' 'git')
optdepends=('fortune-mod: for poetic inspiration')
source=("git://github.com/xyproto/rubyroom.git#tag=$pkgver"
        "http://rubyroom.rubyforge.org/rubyroom.png")
md5sums=('SKIP'
         '9a1fe6c9d67679c0d4dbbdf78a233cba')

prepare() {
  convert "$pkgname.png" -crop 48x48+110+80 icon.png
  gendesk -f --pkgname="$pkgname" --pkgdesc="You, your text and yourself" \
    --categories "Office;" --name='RubyRoom'
}

package() {
  install -Dm755 "$pkgname/$pkgname.rb" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 icon.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
}

# vim:set ts=2 sw=2 et: