summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 28f88ffa76fd1c6de51dd384aa900745f6fb68c5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Maintainer: Mario Finelli <mario at finel dot li>
# Contributor: Artem Vorotnikov <artem at vorotnikov dot me>

_gemname=coderay
pkgname=ruby-$_gemname
pkgver=1.1.3
pkgrel=2
pkgdesc="Fast syntax highlighting for selected languages"
arch=(any)
url=http://coderay.rubychan.de
license=(MIT)
depends=(ruby)
checkdepends=(ruby-rake ruby-rspec)
makedepends=(git rubygems ruby-rdoc)
options=(!emptydirs)
source=(git+https://github.com/rubychan/coderay.git?tag=v${pkgver})
sha256sums=('SKIP')

prepare() {
  cd ${_gemname}
  # disable coverage reporting
  sed -i "s/require 'simplecov'//" spec/spec_helper.rb
}

build() {
  cd ${_gemname}
  RELEASE=true gem build ${_gemname}.gemspec
}

check() {
  cd ${_gemname}
  rake spec
}

package() {
  cd ${_gemname}
  local _gemdir="$(gem env gemdir)"

  gem install \
    --ignore-dependencies \
    --no-user-install \
    -i "$pkgdir/$_gemdir" \
    -n "$pkgdir/usr/bin" \
    $_gemname-$pkgver.gem

  rm "$pkgdir/$_gemdir/cache/$_gemname-$pkgver.gem"

  install -Dm0644 MIT-LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}