summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 353d44b71280aeb0a47510c4abbd1d55301172fc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
# Maintainer: DanManN <dnahimov@gmail.com>

pkgname=ros-noetic-costmap-converter
pkgver=0.0.13
_pkgver_patch=0
pkgdesc="ROS : converts costmaps"
url='http://wiki.ros.org/costmap_converter'
arch=('any')
pkgrel=2
license=('BSD')

ros_makedepends=(ros-noetic-catkin)

makedepends=(
  'cmake'
  'ros-build-tools'
  'pkg-config'
  ${ros_makedepends[@]}
)

ros_depends=(
  ros-noetic-roscpp 
  ros-noetic-costmap-2d
  ros-noetic-cv-bridge 
  ros-noetic-dynamic-reconfigure
  ros-noetic-pluginlib 
  ros-noetic-geometry-msgs 
  ros-noetic-nav-msgs
  ros-noetic-message-generation
  ros-noetic-message-runtime
  ros-noetic-roscpp
  ros-noetic-std-msgs
)

depends=(
  ${ros_depends[@]}
  python-rospkg
)

_dir="costmap_converter-${pkgver}/"
source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/rst-tu-dortmund/costmap_converter/archive/${pkgver}.tar.gz")
sha256sums=('f9d55eb31852533bc75a07bc11502b9923e2b6ce2949768a91197b1d4fba7a76')

build() {
  # Use ROS environment variables
  source /usr/share/ros-build-tools/clear-ros-env.sh
  [ -f /opt/ros/noetic/setup.bash ] && source /opt/ros/noetic/setup.bash

  # Create build directory
  [ -d ${srcdir}/build ] || mkdir ${srcdir}/build
  cd ${srcdir}/build

  # Build project
  cmake ${srcdir}/${_dir} \
    -DCATKIN_BUILD_BINARY_PACKAGE=ON \
    -DCMAKE_INSTALL_PREFIX=/opt/ros/noetic \
    -DPYTHON_EXECUTABLE=/usr/bin/python \
    -DSETUPTOOLS_DEB_LAYOUT=OFF
  make
}

package() {
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}/" install
}