summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7a49a22a5f96e6a4646098ffb6d1f7bd5becbbdf (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Philip Goto <philip.goto@gmail.com>

_pkgname=remotely
pkgname=$_pkgname-git
pkgver=r8.8b5f629
pkgrel=2
pkgdesc="A GTK3 VNC Client"
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url="https://gitlab.gnome.org/haecker-felix/Remotely"
license=('GPL3')
depends=('gtk-vnc')
makedepends=('gtk-vnc'
             'meson'
             'vala')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://gitlab.gnome.org/haecker-felix/Remotely.git")
md5sums=('SKIP')

pkgver() {
  cd Remotely
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  rm -rf build
  arch-meson Remotely build
  ninja -v -C build
}

package() {
  DESTDIR="$pkgdir/" ninja -C build install
}