summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6fb1bad638823499a80904bb3c4bb2d6c566e697 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Max Falk <gmdfalk+aur@gmail.com>
# vim: set ts=4 sw=4 et ft=sh:

_pkgname=rcm
pkgname=${_pkgname}-git
pkgver=v1.3.0.r9.gfbb301d
pkgrel=1
pkgdesc="rc file (dotfiles) management"
arch=("any")
url="https://github.com/thoughtbot/$_pkgname"
license=("BSD")
makedepends=("git" "ruby-mustache")
source=("$pkgname::git+https://github.com/thoughtbot/${_pkgname}.git")
options=(!emptydirs)
conflicts=($_pkgname)
provides=($_pkgname)
sha256sums=('SKIP')


pkgver() {
    cd "${srcdir}/${pkgname}"
    git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${pkgname}"
    ./autogen.sh
    ./configure \
        --disable-silent-rules \
        --prefix=/usr
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make DESTDIR="${pkgdir}/" install
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}