summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7ad2780825da9cd3beadd27e65ed4a79d4df2c6e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>

pkgname=quadlet-git
pkgver=0.2.0.r1.g28aaf07
pkgrel=1
pkgdesc="An opinionated tool for easily running podman system containers under systemd"
arch=(x86_64)
url="https://github.com/containers/quadlet"
license=("GPL2")
depends=("systemd" "podman")
makedepends=("meson" "git")
provides=("quadlet")
conflicts=("quadlet")
source=("quadlet::git+https://github.com/containers/quadlet.git")
sha512sums=('SKIP')


pkgver() {
        cd "$srcdir/quadlet"

        git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {

        arch-meson "$srcdir/quadlet" "$srcdir/build"
        meson compile -C build
}

check() {

        meson test -C build
}

package() {

        meson install -C build --destdir "$pkgdir"

        cd "$srcdir/quadlet"
        install -vDm644 "README.md" "$pkgdir/usr/share/doc/$pkgname/README.md"
        cp -vr "docs" "examples" "$pkgdir/usr/share/doc/$pkgname"
}