summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 67091de6c2824812e8117cc64ec2c4331bc89ea5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org> -> https://github.com/FabioLolix
# Contributor: alex korobtsov <korobcoff@gmail.com>
# Contributor: Alexander Bantyev <balsoft@yandex.ru>

pkgname=qomp
pkgver=1.4
pkgrel=3
pkgdesc="Quick(Qt) Online Music Player"
arch=(i686 x86_64)
url="https://github.com/qomp/qomp"
license=(GPL2)
depends=(taglib qt5-base qt5-x11extras
         qt5-multimedia qt5-xmlpatterns
         gstreamer libcue gst-plugins-good)
optdepends=('gst-libav: additional codecs'
            'gst-plugins-bad: additional codecs'
            'gst-plugins-ugly: additional codecs')
makedepends=(git cmake qt5-tools)
source=("git+https://github.com/qomp/qomp#tag=${pkgver}"
        "git+https://github.com/qomp/translations"
        "git+https://github.com/qomp/themes"
        "git+https://github.com/wadealer/SingleApplication")
sha256sums=('SKIP'
         'SKIP'
         'SKIP'
         'SKIP')

prepare() {
  cd "${srcdir}/${pkgname}"

  git submodule init
  git config 'submodule.translations.url' "${srcdir}/translations"
  git config 'submodule.themes.url' "${srcdir}/themes"
  git config 'submodule.src/singleapplication.url' "${srcdir}/SingleApplication"
  git submodule update

}

build() {
  cd "${srcdir}/${pkgname}"

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr/ \
	-DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  cd "${srcdir}/${pkgname}"
  make DESTDIR="${pkgdir}/"  install
}