summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 36c7f92c43dd166044bb51dc7421dbef1c65878e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
# Maintainer:  twa022 <twa022 at gmail dot com>

_pkgname=keybinder
pkgname=python2-keybinder2
pkgver=0.3.1
pkgrel=3
pkgdesc='Library for registering global keyboard shortcuts (Python 2 bindings)'
arch=('i686' 'x86_64' 'mips64el' 'armv6h' 'armv7h' 'arm' 'aarch64')
url='https://github.com/kupferlauncher/keybinder'
license=('GPL')
depends=('pygtk' 'libkeybinder2')
makedepends=('gobject-introspection')
options=('!emptydirs')
source=("https://github.com/kupferlauncher/${_pkgname}/releases/download/v${pkgver}/${_pkgname}-$pkgver.tar.gz")
sha256sums=('879f07130ac64792ddb9fd758e6673119283bda37d75573787ae22af8684a240')

build() {
  cd "${_pkgname}-${pkgver}"
  ./configure --prefix=/usr PYTHON=python2 --disable-lua
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  make -C docs DESTDIR="${pkgdir}" uninstall
  make -C libkeybinder DESTDIR="${pkgdir}" uninstall
}