summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 2c1fdc0891be0ae76c633011ce9164c3c23b9c18 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: pfm <vorticity at mail dot ru>
pkgname=("python-txacme" "python2-txacme")
_pkgname=txacme
pkgver=0.9.3
pkgrel=1
pkgdesc="ACME protocol implementation for Twisted"
arch=(any)
url="https://txacme.readthedocs.io"
license=('MIT')
makedepends=("python-setuptools" "python2-setuptools")
source=("$_pkgname-$pkgver.tar.gz::https://github.com/twisted/$_pkgname/archive/$pkgver.tar.gz")
md5sums=('78b2dea6877a23910a33d47a4d79bf90')

prepare() {
    cp -a $_pkgname-$pkgver{,-py2}
}

build() {
    cd "$srcdir/$_pkgname-$pkgver"
    python setup.py build

    cd "$srcdir/$_pkgname-$pkgver-py2"
    python2 setup.py build
}

package_python-txacme() {
    depends=("python")
    cd "$srcdir/$_pkgname-$pkgver"
    python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_python2-txacme() {
    depends=("python2")
    cd "$srcdir/$_pkgname-$pkgver-py2"
    python2 setup.py install --root="$pkgdir/" --optimize=1 --skip-build
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}