summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 82db6a802de4e2f77bfd7afb91463739824ade1c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>

pkgname=python-sqliteschema
pkgver=1.2.0
pkgrel=1
pkgdesc='Dump table schema of a SQLite database file'
arch=('any')
url='https://github.com/thombashi/sqliteschema'
license=('MIT')
depends=(
  'python>=3.6'
  ## ALL DEPS BELOW THIS COMMENT ARE AUR ONLY
  'python-mbstrdecoder>=0.8.3'
  'python-mbstrdecoder<2'
  'python-tabledata>=1.0.0'
  'python-tabledata<2'
  'python-typepy>=1.1.4'
  'python-typepy<2')
makedepends=('python-setuptools')
checkdepends=('python-pytest-runner' 'python-simplesqlite>=1')
source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/s/sqliteschema/sqliteschema-$pkgver.tar.gz"
        "$pkgname-$pkgver.tar.gz.asc::https://files.pythonhosted.org/packages/source/s/sqliteschema/sqliteschema-$pkgver.tar.gz.asc")
sha256sums=('4c18f141239c58b6dbdc69130be41ed9740d8209a7ab6d529ba982a8b79c071a'
            'SKIP')
validpgpkeys=('BCF9203E5E80B5607EAE6FDD98CDA9A5F0BFC367')

build() {
  cd "sqliteschema-$pkgver"
  python setup.py build
}

check() {
  cd "sqliteschema-$pkgver"
  python setup.py pytest
}

package() {
  cd "sqliteschema-$pkgver"
  PYTHONHASHSEED=0 python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm 644 README.rst -t "$pkgdir/usr/share/doc/$pkgname"
  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}

# vim: ts=2 sw=2 et: