summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5935417fec847c6f1eef15b2b5d367451073e8b3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
# Contributor: Florian Wittmann

_pkgname='SimpleSQLite'
pkgname="python-${_pkgname,,}"
pkgver=1.1.3
pkgrel=2
pkgdesc='Simplify SQLite database operations'
arch=('any')
url='https://github.com/thombashi/SimpleSQLite'
_url_pypi='https://pypi.org/project/SimpleSQLite'
license=('MIT')
depends=('python'
        'python-dataproperty'
        'python-mbstrdecoder'
        'python-pathvalidate'
        'python-sqliteschema'
        'python-tabledata'
        'python-typepy')
makedepends=('python-setuptools')
source=("https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('e4f3613b04bc304a2f41294367c628ed00f27ca5d8eceb3f1a9d674f4b483b95')

build() {
  cd "${_pkgname}-${pkgver}"
  python setup.py build
}

package() {
  cd "${_pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  install -Dvm644 'README.rst' -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dvm644 'LICENSE' -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim: ts=2 sw=2 et: