summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 267693f63abda2a57174453d27e92da2e0bff3bb (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: robertfoster

pkgbase=python-fastjsonschema
pkgname=('python-fastjsonschema' 'python2-fastjsonschema')
pkgver=2.14.4
pkgrel=1
pkgdesc="Fastest Python implementation of JSON schema"
arch=('any')
url="https://github.com/horejsek/python-fastjsonschema"
license=('BSD3')
source=("https://github.com/horejsek/python-fastjsonschema/archive/v$pkgver.tar.gz")
makedepends=('python2-setuptools' 'python-setuptools')

prepare() {
  cp -a $pkgbase-$pkgver{,-py2}
}

build() {
  cd "$srcdir"/$pkgbase-$pkgver
  python setup.py build

  cd "$srcdir"/$pkgbase-$pkgver-py2
  python2 setup.py build
}

package_python-fastjsonschema() {
  depends=('python')

  cd $pkgbase-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
}

package_python2-fastjsonschema() {
  depends=('python2')

  cd $pkgbase-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
}

md5sums=('98d94e472ea56ac94f0606b1f0453f6c')