summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 59024b7467a47b61b505fad75d4cba5e6d416949 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Maintainer: Eric Langlois <eric@langlois.xyz>
pkgname=python-dowel
_name=${pkgname#python-}
pkgver=0.0.3
pkgrel=2
pkgdesc="A logger for machine learning research"
arch=('any')
url="https://github.com/rlworkgroup/dowel"
license=('MIT')
depends=(
	'python-dateutil'
	'python-matplotlib'
	'python-numpy'
	'python-scipy'
	'python-tabulate'
	'python-tensorboardx'
)
optdepends=(
	'tensorboard: Output to tensorboard'
)
makedepends=('python-setuptools')
checkdepends=(
	'python-pytest'
	'python-pytest-cov'
	'python-pytest-xdist'
)
source=("https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz")
sha256sums=('aac42c226c15941ba676ca6167bae296fd617f312f8dc456dffc95f561f35c8e')

build() {
	cd "$_name-$pkgver"
	python setup.py build
}

check() {
	cd "$_name-$pkgver/build/lib"
	python -m pytest "$srcdir/$_name-$pkgver/tests" \
		--ignore "$srcdir/$_name-$pkgver/tests/$_name/test_tensor_board_output.py"
}

package() {
	cd "$_name-$pkgver"
	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
	install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}