summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 5679cd88534df48895de161dd2c1aa98b5d68683 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: silvermight <silver@silvermight.com>
pkgname=python-discord-git
pkgver=r1919.91e00d84
pkgrel=1
pkgdesc="A modern, easy to use, feature-rich, and async ready API wrapper for Discord"
arch=('any')
url="https://github.com/Rapptz/discord.py"
license=('MIT')
depends=('python' 'python-websockets' 'python-aiohttp')
optdepends=('python-pynacl: Voice support'
            'libffi: Voice support')
makedepends=('git')
source=("python-discord-git::git+https://github.com/Rapptz/discord.py.git")
provides=('python-discord')
conflicts=('python-discord')
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/python-discord-git"
  python setup.py build
}

package() {
  cd "$srcdir/python-discord-git"
  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}