summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b83e83e852747c6a99b9e99207af7a24805b57c3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>

pkgname=pwncat
pkgver=0.1.1
pkgrel=1
pkgdesc='Netcat on steroids with Firewall, IDS/IPS evasion, bind and reverse shell, self-injecting shell and port forwarding magic - and its fully scriptable with Python (PSE)'
arch=('any')
url='https://cytopia.github.io/pwncat'
license=('MIT')
depends=('python')
makedepends=('python-setuptools')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/cytopia/pwncat/archive/v${pkgver}.tar.gz")
sha256sums=('24c52fd9463c91217b7c7405a6cdb567d14e0de586a2a34cf226a8d4a3467776')

build() {
  cd "${pkgname}-${pkgver}"
  python setup.py build
  gzip --force man/pwncat.1
}

package() {
  cd "${pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 *.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -Dm644 man/pwncat.1.gz -t "${pkgdir}/usr/share/man/man1"
}
# vim:set ts=2 sw=2 et: