summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 0ad351bc569cea0299f586b04764cfd12cd5763c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>

pkgname=puddletag-git
pkgver=2.0.1.r26.g66aa1f4
pkgrel=1
pkgdesc="An audio tag editor for GNU/Linux, git version"
url="https://github.com/puddletag/puddletag"
license=('GPL3')
arch=('any')
depends=('python-mutagen' 
	 'python-pyparsing' 
	 'python-configobj' 
	 'python-pyqt5' 
	 'qt5-svg' 
	 'python-pillow')
makedepends=('git')
optdepends=('chromaprint: AcoustID support' 
	    'quodlibet: QuodLibet library support')
provides=('puddletag')
conflicts=('puddletag')
replaces=('puddletag-qt5-git')
source=("${pkgname}::git+https://github.com/puddletag/puddletag")
sha256sums=('SKIP')

pkgver() {
  cd "${pkgname}"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${pkgname}/source"
  python setup.py config
}

package() {
  cd "${pkgname}/source"
  python setup.py install --root="${pkgdir}" --optimize=1
}