summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 21118262d5e4e774404cba4d509e91dd40a5d5b6 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Sergey Slipchenko <faergeek@gmail.com>
pkgname=plymouth-lite-rbp-git
pkgver=r10.76e20e8
pkgrel=1
pkgdesc="Plymouth-lite patched and ready for Raspberry Pi"
arch=('armv7h')
url="https://github.com/T4d3o/Plymouth-lite"
license=('GPL2')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('plymouth-lite-rbp::git+https://github.com/T4d3o/Plymouth-lite.git'
        '01-change-systemd-unit.patch' 'initcpio_hook' 'initcpio_install')
md5sums=('SKIP'
         '709d24411c2fcd62b2eccbfc98010b25'
         '86dcab222ab4be45fc96d2792ff91809'
         'e13f4e22ee8e28eef85028c9307bfc3f')

pkgver() {
  cd "$srcdir/${pkgname%-git}"

  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/${pkgname%-git}"
  patch -Np1 -i "$srcdir/01-change-systemd-unit.patch"
}

build() {
  cd "$srcdir/${pkgname%-git}"
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  make DESTDIR="$pkgdir/" install
  mkdir -p $pkgdir/usr/lib/systemd/system/
  install -Dm0644 systemd/* $pkgdir/usr/lib/systemd/system/
  install -D -m644 "${srcdir}"/initcpio_hook "${pkgdir}"/usr/lib/initcpio/hooks/plymouth-lite
  install -D -m644 "${srcdir}"/initcpio_install "${pkgdir}"/usr/lib/initcpio/install/plymouth-lite
}