summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 4c4c83ff25cdcb3f3b87ebe5f35bb141fac20d85 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
# Maintainer: Markus Härer <markus.haerer@gmx.net>
# Based on plasma-volume-control-git from Antonio Rojas

_srcname=plasma-pa
pkgname=${_srcname}-git
pkgver=r322.d50ee61
pkgrel=2
pkgdesc='Volume applet for Plasma'
arch=('i686' 'x86_64')
url='http://quickgit.kde.org/?p=plasma-pa.git'
license=('LGPL')
depends=('pulseaudio' 'plasma-workspace')
makedepends=('extra-cmake-modules-git' 'git' 'kdoctools-git')
provides=('plasma-volume-control' 'plasma-pa')
conflicts=('plasma-volume-control' 'plasma-volume-control-git' 'plasma-pa')
source=('git://anongit.kde.org/plasma-pa.git')
md5sums=('SKIP')

pkgver() {
  cd ${srcdir}/${_srcname}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir -p ${srcdir}/${_srcname}/build
}

build() {
  cd ${srcdir}/${_srcname}/build
  cmake .. \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=lib \
    -DKDE_INSTALL_USE_QT_SYS_PATHS=ON \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd ${srcdir}/${_srcname}/build
  make DESTDIR="${pkgdir}" install
}