summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: eecb554f142ecae3c12eb17cc21e0935e4f7ebce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: dracorp aka Piotr Rogoza <piotr.r.public at gmail.com>

pkgname=perl-text-hunspell
pkgver=2.14
pkgrel=1
_author=C/CO/COSIMO
_perlmod=Text-Hunspell
pkgdesc='Text::Hunspell - Perl interface to the GNU Hunspell library'
arch=('i686' 'x86_64')
url="http://search.cpan.org/dist/Text-Hunspell/"
license=('GPL' 'PerlArtistic')
depends=(
hunspell
)
makedepends=(
hunspell
perl-extutils-pkgconfig
perl-alien-hunspell
)
options=(!emptydirs)
source=("http://search.cpan.org/CPAN/authors/id/$_author/$_perlmod-$pkgver.tar.gz")
sha256sums=('22e1000b566b8a3d34fdb2f8afa8130e2fc28e81773c5b67dfd020ef41c53406')
unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps MODULEBUILDRC=/dev/null
build(){
  cd "$srcdir"/$_perlmod-$pkgver

  if [ -f Makefile.PL ]; then
    /usr/bin/perl Makefile.PL
    make
  else
    /usr/bin/perl Build.PL
    ./Build
  fi
}
check(){
  cd "$srcdir"/$_perlmod-$pkgver

  if [ -f Makefile.PL ]; then
    make test
  else
    ./Build test
  fi
}
package(){
  cd "$srcdir"/$_perlmod-$pkgver

  if [ -f Makefile.PL ]; then
    make install INSTALLDIRS=vendor DESTDIR="$pkgdir"
  else
    ./Build install --installdirs=vendor --destdir="$pkgdir"
  fi
}