summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b34600d70043fe50011bbf5fec409584d0119dc4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
# Contributor: Phillip Smith <pkgbuild@phs.id.au>

### I AM ONLY THE PACKAGER, NOT THE DEVELOPER
### Please ask support questions about this software in one of:
###   1) The AUR comments; OR
###   2) Upstream forums/maillist etc; OR
###   3) The ArchLinux forums
### I do not always know enough about the software itself, or don't have the
### time to promptly respond to direct emails.
### If you have found a problem with the package/PKGBUILD (as opposed to
### the software) then please do email me or post an AUR comment.

pkgname=perl-net-rabbitmq
pkgver=0.2.8
pkgrel=1
pkgdesc="Interact with RabbitMQ over AMQP using librabbitmq"
arch=('any')
url="http://search.cpan.org/dist/Net--RabbitMQ/"
license=('GPL' 'PerlArtistic')
depends=('perl' )
options=('!emptydirs')
source=("http://search.cpan.org/CPAN/authors/id/J/JE/JESUS/Net--RabbitMQ-${pkgver}.tar.gz")
md5sums=('80d0f765fe44c9e0e0c9747e2e64c1d1')

build() {
  cd "$srcdir"/Net--RabbitMQ-$pkgver

  # remove files that shouldn't be in the tarball and mess with building
  # refer: https://rt.cpan.org/Public/Bug/Display.html?id=78353
  rm -f ._*

  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd "$srcdir"/Net--RabbitMQ-$pkgver
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  make DESTDIR="$pkgdir" install
  chmod -R u=rwX,go=rX "$pkgdir"
}

# vim:set ts=2 sw=2 et: