summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 7916a5ffc76e8c3046f887684025cd72fe42a1ce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: Přemysl Janouch <p.janouch@gmail.com>
pkgname=pdf-simple-sign-git
_pkgname=pdf-simple-sign
pkgver=r2.41f8165
pkgrel=1
pkgdesc="Simple PDF signer"
url="https://git.janouch.name/p/pdf-simple-sign"
arch=('i686' 'x86_64')
license=('BSD')
options=(zipman)
conflicts=('pdf-simple-sign')
provides=('pdf-simple-sign')
makedepends=('meson' 'git')
depends=('openssl')
source=("git+https://git.janouch.name/p/$_pkgname.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  ( set -o pipefail
    git describe --long --tags 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

build() {
  rm -rf "$srcdir/$_pkgname-build"
  mkdir "$srcdir/$_pkgname-build"
  cd "$srcdir/$_pkgname-build"
  meson --prefix=/usr --buildtype release "$srcdir/$_pkgname"
  ninja
}

package() {
  cd "$srcdir/$_pkgname-build"
  DESTDIR=$pkgdir ninja install 
}