summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: d89131aa057e611b24884e97b92ab812a516e3b7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
# Maintainer: Willem Mulder <14mRh4X0r@gmail.com>
_pkgname=passff-host
pkgname=$_pkgname-git
pkgver=1.0.1.r7.1feab77
pkgrel=1
pkgdesc="Host app for the WebExtension PassFF"
arch=(any)
url="https://github.com/passff/passff-host"
license=('GPL2')
depends=('python')
makedepends=(git jq)
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+https://github.com/passff/passff-host.git")
sha384sums=('SKIP')

pkgver() {
  cd "$_pkgname"
  printf "%s" "$(git describe --tags --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

package() {
  cd "$_pkgname"

  sed -i -e '1c#!/usr/bin/python3' -e s/_VERSIONHOLDER_/${pkgver}/g src/passff.py

  install -Dm755 src/passff.py \
    "${pkgdir}/usr/lib/mozilla/native-messaging-hosts/passff.py"
  jq '.path = "/usr/lib/mozilla/native-messaging-hosts/passff.py"' src/passff.json \
    > "${pkgdir}/usr/lib/mozilla/native-messaging-hosts/passff.json"
}

# vim:set ts=2 sw=2 et: