summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: b9a09635c56abee1d640c337751e6666023cfc5f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
# Maintainer: Julian Hauser <julian at julianhauser.com>
# PKGBUILD adapted from papis, maintained by JP-Ellis <josh@jpellis.me>

pkgname=papis-git
_pkgname=papis
pkgver=0.11.1.r22.g5599763
pkgrel=1
pkgdesc="A powerful and highly extensible command-line document and bibliography manager. Git version."
arch=('any')
url="https://github.com/papis/papis"
license=('GPL')
makedepends=('git')
depends=('python'
         'python-requests'
         'python-filetype'
         'python-pyparsing'
         'python-arxiv2bib'
         'python-pyaml'
         'python-chardet'
         'python-beautifulsoup4'
         'python-colorama'
         'python-bibtexparser'
         'python-click'
         'python-habanero'
         'python-isbnlib'
         'python-prompt_toolkit'
         'python-tqdm'
         'python-pygments'
         'python-stevedore'
         'python-doi'
         'python-typing_extensions'
         'python-lxml'
         'python-slugify'
        )
optdepends=('papis-rofi: integration with rofi' 'papis-zotero: imports from zotero')
provides=("papis")
conflicts=("papis")
source=("git+https://github.com/papis/papis.git")
sha256sums=('SKIP')
noextract=()

pkgver() {
  cd "${_pkgname}"
  git describe --long --tags | sed 's/v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "${_pkgname}"
  sed -i '/configparser/d' setup.py
  python setup.py build
}

package() {
  cd "${_pkgname}"
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}